一、CMake的HelloWorld编译

  1. 写一个Hello World

    #include <cstdio>
    int main(){
        printf("Hello World");
        return 0;
    }

  2. 写一个CMakeLists.txt

    PROJECT (HELLO)

    SET(SRC_LIST main.cpp)

    MESSAGE(STATUS "This is BINARY dir" ${HELLO_BINARY_DIR})
    MESSAGE(STATUS "This is SOURCE dir" ${HELLO_SOURCE_DIR})

    ADD_EXECUTABLE(hello ${SRC_LIST})

  3. 控制台输入命令：

    cmake .

  4. 然后就生成了一个名为HELLO的VS工程

二、CMake语法介绍

2.1 关键字

2.1.1 PROJECT

用于指定工程的名字和支持的语言，默认支持所有语言

PROJECT(HELLO) 			# 指定了工程的名字, 并支持所有语言--建议
PROJECT(HELLO CXX)		# 指定了工程的名字, 并且支持语言为C++
PROJECT(HELLO C CXX)	# 指定了工程的名字, 并且支持语言为C和C++

该指定隐式定义了两个CMake的变量

<projectname>_BINARY_DIR
<projectname>_SOURCE_DIR

MESSAGE关键字就可以直接使用这两个变量，当前都指向当前的工作目录

  1. 问题：如果改了工程名，这两个变量名也会改变
  2. 解决：CMake有两个预定义变量：PROJECT_BINARY_DIR和PROJECT_SOURCE_DIR，这两个变量和HELLO_BINARY_DIR，HELLO_SOURCE_DIR是一致的。所以改了工程名也没有关系

2.1.2 SET关键字

显式指定变量

SET(SRC_LIST main.cpp)    				# 令SRC_LIST变量包含main.cpp
SET(SRC_LIST main.cpp t1.cpp t2.cpp)	# 令SRC_LIST变量包含main.cpp、t1.cpp、t2.cpp

2.1.3 MESSAGE关键字

向终端输出用户自定义的信息，主要包含三种信息：

  • SEND_ERROR：如果产生错误，那么生成过程就会被跳过
  • SATUS：输出前缀为--的信息
  • FATAL_ERROR：立即终止所有 cmake 过程.

2.1.4 ADD_EXECUTABLE关键字

生成可执行文件

ADD_EXECUTABLE(hello ${SRC_LIST})	#生成的可执行文件名是hello, 源文件读取变量SRC_LIST中的内容
ADD_EXECUTABLE(hello main.cpp)		#本例中两者含义相同

上述例子可以简化的写成

PROJECT(HELLO)
ADD_EXECUTABLE(hello main.cpp)

注意：工程名的 HELLO 和生成的可执行文件 hello 是没有任何关系的

2.2 语法的基本原则

  • 变量使用${}方式取值，但是在 IF 控制语句中是直接使用变量名

  • 指令(参数 1 参数 2...) 参数使用括弧括起，参数之间使用空格或分号分开

    • 以上面的 ADD_EXECUTABLE 指令为例，如果存在另外一个 func.cpp 源文件，就要写成：

      ADD_EXECUTABLE(hello main.cpp func.cpp)
      ADD_EXECUTABLE(hello main.cpp;func.cpp)

  • 指令是大小写无关的，参数和变量是大小写相关的。但推荐全部使用大写指令

  • SET(SRC_LIST main.cpp)可以写成 SET(SRC_LIST “main.cpp”)

    • 如果源文件名中含有空格，就必须要加双引号

  • ADD_EXECUTABLE(hello main)后缀可以不写，它会自动去找.c和.cpp

    • 最好不要这样写，可能会有这两个文件main.cpp和main

三、内部构建和外部构建

  • 上述例子就是内部构建，它生成的临时文件特别多，不方便清理
  • 外部构建，就会把生成的临时文件放在build目录下，不会对源文件有任何影响
  • 强烈建议使用外部构建方式
mkdir build
cd build
cmake ..

注意外部构建的两个变量

HELLO_SOURCE_DIR  # 还是工程路径
HELLO_BINARY_DIR  # 编译路径 也就是 /root/cmake/bulid

四、让Hello World看起来更像一个工程

  • 为工程添加一个子目录 src，用来放置工程源代码
  • 添加一个子目录 doc，用来放置这个工程的文档 hello.txt
  • 在工程目录添加文本文件 COPYRIGHT, README
  • 在工程目录添加一个 runhello.sh 脚本，用来调用 hello 二进制
  • 将构建后的目标文件放入构建目录的 bin 子目录
  • 将 doc 目录 的内容以及 COPYRIGHT/README 安装到/usr/share/doc/cmake/

4.1 将目标文件放入构建目录的 bin 子目录

每个目录下都要有一个CMakeLists.txt

├── build
├── CMakeLists.txt
└── src
    ├── CMakeLists.txt
    └── main.cpp

  1. 外层CMakeLists.txt

    PROJECT(HELLO)
    ADD_SUBDIRECTORY(src bin)

  2. src下的CMakeLists.txt

    ADD_EXECUTABLE(hello main.cpp)

4.2 ADD_SUBDIRECTORY 指令

向当前工程添加存放源文件的子目录，并可以指定中间二进制和目标二进制存放的位置

ADD_SUBDIRECTORY(source_dir [binary_dir] [EXCLUDE_FROM_ALL])
  • EXCLUDE_FROM_ALL函数是将写的目录从编译中排除，如程序中的example
  • ADD_SUBDIRECTORY(src bin)
    • 将 src 子目录加入工程并指定编译输出(包含编译中间结果)路径为bin 目录
    • 如果不进行 bin 目录的指定，那么编译结果(包括中间结果)都将存放在build/src 目录

4.3 更改二进制的保存路径

SET指令重新定义EXECUTABLE_OUTPUT_PATH和LIBRARY_OUTPUT_PATH变量，来指定最终的目标二进制的位置

SET(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/bin)
SET(LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/lib)

五、使用CMake进行安装

  • 一种是从代码编译后直接 make install 安装
  • 一种是打包时的指定 目录安装。
    • 简单的可以这样指定目录：make install DESTDIR=/tmp/test
    • 稍微复杂一点可以这样指定目录：./configure –prefix=/usr

5.1 如何安装HelloWord

使用CMAKE一个新的指令：INSTALL

  • INSTALL的安装可以包括：二进制、动态库、静态库以及文件、目录、脚本等

使用CMAKE一个新的变量：CMAKE_INSTALL_PREFIX

// 目录树结构
├── build
├── CMakeLists.txt
├── COPYRIGHT
├── doc
│   └── hello.txt
├── README
├── runhello.sh
└── src
    ├── CMakeLists.txt
    └── main.cpp

5.2 安装文件COPYRIGHT和README

PROJECT(HELLO)
ADD_SUBDIRECTORY(src bin)
INSTALL(FILES COPYRIGHT README DESTINATION share/doc/cmake/)

FILES：文件

DESTINATION：目标路径，可以写绝对路径，也可以写相对路径

  1. 相对路径实际路径是：${CMAKE_INSTALL_PREFIX}/<DESTINATION 定义的路径>
    • CMAKE_INSTALL_PREFIX默认是在usr/local/
    • cmake -DCMAKE_INSTALL_PREFIX=/usr在cmake的时候指定CMAKE_INSTALL_PREFIX变量的路径

5.3 安装脚本runhello.sh

INSTALL(PROGRAMS runhello.sh DESTINATION bin)

PROGRAMS：非目标文件的可执行程序安装(比如脚本之类)

  • 说明：实际安装到的是/usr/local/bin

5.4 安装目录/doc中的 hello.txt

INSTALL(DIRECTORY doc/ DESTINATION share/doc/cmake)

DIRECTORY 后面连接的是所在 Source 目录的相对路径

  1. 注意：abc 和 abc/有很大的区别
    1. 目录名不以/结尾：这个目录将被安装为目标路径下的
    2. 目录名以/结尾：将这个目录中的内容安装到目标路径

5.5 安装过程

cmake ..
make
make install

六、静态库和动态库的构建

任务：

  1. 建立一个静态库和动态库，提供 HelloFunc 函数供其他程序编程使用，HelloFunc 向终端输出 Hello World 字符串
  2. 安装头文件与共享库

6.1 静态库和动态库的区别

  • 静态库的扩展名一般为“.a”或“.lib”；动态库的扩展名一般为“.so”或“.dll”。
  • 静态库在编译时会直接整合到目标程序中，编译成功的可执行文件可独立运行
  • 动态库在编译时不会放到连接的目标程序中，即可执行文件无法单独运行。

6.2 构建实例

├── build
├── CMakeLists.txt
└── lib
    ├── CMakeLists.txt
    ├── hello.cpp
    └── hello.h
// hello.h
#ifndef HELLO_H
#define Hello_H
void HelloFunc();
#endif

// hello.cpp
#include "hello.h"
#include <iostream>
void HelloFunc(){
    std::cout << "Hello World" << std::endl;
}

最外层的CMakeLists.txt

PROJECT(HELLO)
ADD_SUBDIRECTORY(lib bin)

lib中的CMakeLists.txt

SET(LIBHELLO_SRC hello.cpp)
ADD_LIBRARY(hello SHARED ${LIBHELLO_SRC})

6.3 ADD_LIBRARY关键字

ADD_LIBRARY(hello SHARED ${LIBHELLO_SRC})
  • hello：就是正常的库名，生成的名字前面会加上lib，最终产生的文件是libhello.so
  • SHARED，动态库 STATIC，静态库
  • ${LIBHELLO_SRC} ：源文件

七、同时构建静态和动态库

# 如果用这种方式，只会构建一个动态库，不会构建出静态库，虽然静态库的后缀是.a
ADD_LIBRARY(hello SHARED ${LIBHELLO_SRC})
ADD_LIBRARY(hello STATIC ${LIBHELLO_SRC})

# 修改静态库的名字，这样是可以的，但是我们往往希望他们的名字是相同的，只是后缀不同而已
ADD_LIBRARY(hello SHARED ${LIBHELLO_SRC})
ADD_LIBRARY(hello_static STATIC ${LIBHELLO_SRC})

7.1 SET_TARGET_PROPERTIES关键字

这条指令可以用来设置输出的名称，对于动态库，还可以用来指定动态库版本和 API 版本

SET(LIBHELLO_SRC hello.cpp)

# 生成静态库
ADD_LIBRARY(hello_static STATIC ${LIBHELLO_SRC})
# 重名为hello
SET_TARGET_PROPERTIES(hello_static PROPERTIES OUTPUT_NAME "hello")
# cmake在构建一个新的target时,会尝试清理掉其他使用这个名字的库
# 因为在构建libhello.so时, 就会清理掉 libhello.a
SET_TARGET_PROPERTIES(hello_static PROPERTIES CLEAN_DIRECT_OUTPUT 1)

# 生成共享库
ADD_LIBRARY(hello SHARED ${LIBHELLO_SRC})
# 重命名为hello
SET_TARGET_PROPERTIES(hello PROPERTIES OUTPUT_NAME "hello")
SET_TARGET_PROPERTIES(hello PROPERTIES CLEAN_DIRECT_OUTPUT 1)

7.2 动态库的版本号

SET_TARGET_PROPERTIES(hello PROPERTIES VERSION 1.2 SOVERSION 1)
  1. VERSION：动态库版本
  2. SOVERSION：API 版本

7.3 安装共享库和头文件

本例中我们将 hello 的共享库安装到<prefix>/lib目录，

将 hello.h 安装到<prefix>/include/hello目录

# 文件放到该目录下
INSTALL(FILES hello.h DESTINATION include/hello)

# 二进制，静态库，动态库安装都用TARGETS
# ARCHIVE 特指静态库，LIBRARY 特指动态库，RUNTIME 特指可执行目标二进制。
INSTALL(TARGETS hello hello_static LIBRARY DESTINATION lib ARCHIVE DESTINATION lib)

注意：安装的时候，指定一下路径，放到系统下

cmake -D CMAKE_INSTALL_PREFIX=/usr ..

八、使用外部共享库和头文件

├── build
├── CMakeLists.txt
└── src
    ├── CMakeLists.txt
    └── main.cpp
// main.cpp
#include <hello.h>
int main(){
	HelloFunc();
}

最外层的CMakeLists.txt

PROJECT(HELLO)
ADD_SUBDIRECTORY(src bin)

src下的CMakeLists.txt

INCLUDE_DIRECTORIES(/usr/include/hello)
ADD_EXECUTABLE(hello main.cpp)
TARGET_LINK_LIBRARIES(hello libhello.so)

8.1 INCLUDE_DIRECTORIES关键字

这条指令可以用来向工程添加多个特定的头文件搜索路径，路径之间用空格分割

INCLUDE_DIRECTORIES(/usr/include/hello)

添加非标准的共享库搜索路径

LINK_DIRECTORIES(/home/myproject/libs)

添加需要链接的共享库，共享库需要在标准路径下

# 链接动态	库
TARGET_LINK_LIBRARIES(main libhello.so)
# 链接静态库
TARGET_LINK_LIBRARIES(main libhello.a)

8.4 特殊的环境变量 CMAKE_INCLUDE_PATH 和 CMAKE_LIBRARY_PATH

  1. 注意：这两个是环境变量而不是 cmake 变量，可以在linux的bash中进行设置
  2. 我们上面例子中使用了绝对路径INCLUDE_DIRECTORIES(/usr/include/hello)来指明include路径的位置
  3. 我们还可以使用另外一种方式，使用环境变量export CMAKE_INCLUDE_PATH=/usr/include/hello

8.5 补充：生产debug版本的方法

cmake .. -D CMAKE_BUILD_TYPE=debug